/* 
Battle Pods
by Cadin Batrack 
9.20.05

PLEASE NOTE: 
This software is incomplete.
I haven't had a chance to work out the bugs or clean up
the code. View at your own risk.

If using without pods:
LEFT = blue fish
DOWN = ruby slippers

SHIFT = yellow fish
x = magic 8 ball
*/


// hardware currently supports 10 pods
// (5 for each player)
// software currently supports 4:
int totalPods = 4;

// array of pods
pod[] podArray = new pod[totalPods];

//image arrays for character images and special weapons
PImage[] imageArray = new PImage[totalPods];
PImage[] specialArray = new PImage[totalPods];

int p1pod, p2pod;
boolean p1isSelected, p2isSelected;
int p1timer, p2timer;

//misc images
PImage bg, blank_b, blank_y, sp1, sp2; 

boolean released;

void setup() {
  size(700,350);
  
  //load interface
  bg = loadImage("background.jpg");
  blank_b= loadImage("ch_blank_b.jpg");
  blank_y= loadImage("ch_blank_y.jpg");
  
   //populate image Array
  for (int i = 0; i <imageArray.length; i++) {
    imageArray[i] = loadImage("ch_"+i+".jpg");
  }

  //player one inactive
  p1pod = 0;
  p1isSelected = false;
  
  //player two inactive
  p2pod = 0;
  p2isSelected = false;

  //populate pod Array
  for (int i = 0; i < podArray.length; i++) {
    podArray[i] = new pod(i);
  }

} //end setup



void draw() {
  image(bg,0,0);

  // display player 1 if there's a pod in his bay
  if(p1isSelected) {
    podArray[p1pod].displayPod();
  } else {
    image(blank_b, 33,58);
  }
  
  
  // display player 2 if there's a pod in his bay
  if(p2isSelected) {
    podArray[p2pod].displayPod();
  } else {
    image(blank_y, 480,58);
  }

  //doing this strange dance with timers and such because the
  //foil connection on the pods is not constant

  //if player 1 detects a pod reset timer
  if(keyPressed && (keyCode == LEFT || keyCode == DOWN)){
    p1timer=40;
  } 
  else{
    //otherwise decrease it
    p1timer--;
  }
  
  //ditto for player 2
  if(keyPressed &&(key == 'x' || keyCode == SHIFT)){
    p2timer=40;
  } 
  else{
    p2timer--;
  }

  // if the timer runs out (no pod detected for X cycles)
  // set the pod bay to emtpy
  if(p1timer < 1 && p1isSelected){
    
    println("player 1 = " + p1pod);
    p1isSelected = false;
  } 
  
  // same here for p2
  if(p2timer < 1 && p2isSelected){
   
    println("player 2 = " + p2pod);
    p2isSelected = false;
  } 
  
}// end void draw()


void keyPressed() {
  
  //p1
  if(keyCode == LEFT || keyCode == DOWN){
    if(!p1isSelected){
      if(keyCode == LEFT){
        p1pod = 0; // blue fish
      } 
      else if(keyCode == DOWN){
        p1pod = 2; // ruby slippers
      } 
      p1isSelected=true;
      println("player 1 = " + p1pod);

    }
  }

  //p2
  if(key == 'x' || keyCode == SHIFT){
    if(!p2isSelected){
      if(key == 'x'){
        p2pod = 3; // magic 8 ball
      } 
      else if(keyCode == SHIFT){
        p2pod = 1; // yellow fish
      } 
      p2isSelected=true;
      p2timer=20;
      println("player 2 = " + p2pod);
    }
  }
} //end void keyPressed


//pod class
class pod {
  PImage img;
  PImage special;
  int podNumber;
  int attack,defense,energy;
  
  //CONSTRUCTOR
  pod(int _podNumber) {
    img = imageArray[_podNumber];  
    
    //random values for now
    special = specialArray[_podNumber];
    attack = floor(random(1,8));
    defense = floor(random(1,8));
    energy = 8;
    
    podNumber = _podNumber;
  }
  
  void displayPod() {
    noStroke();
    if(podNumber % 2 == 0){
    
      //Player 1 properties    
      image(img,33,58);
      
      //attack meter
      fill(234,0,255);
      for(int i=0;i<attack;i++){
        rect(106+(i*13)+i,245,13,7);
      }
    
      //defense meter
      fill(0,37,177);
      for(int i=0;i<defense;i++){
        rect(106+(i*13)+i,263,13,7);
      }
    
      //energy meter
      fill(0,234,255);
      for(int i=0;i<energy;i++){
        rect(106+(i*13)+i,281,13,7);
      }
      
      
    } else {
    
      //Player 2 properties
      image(img, 480,58);
      
      //attack meter
      fill(234,0,255);
      for(int i=0;i<attack;i++){
        rect(579-(i*13)-i,245,13,7);
      }
    
      //defense meter
      fill(176,172,56);
      for(int i=0;i<defense;i++){
        rect(579-(i*13)-i,263,13,7);
      }
    
      //energy meter
      fill(255,246,0);
      for(int i=0;i<energy;i++){
        rect(579-(i*13)-i,281,13,7);
      }
    } 
    
  }

}// end pod class